home *** CD-ROM | disk | FTP | other *** search
/ AmigActive 26 / AACD 26.iso / AACD / Programming / ace_gpl_release / src / lib / asm / gfx.s < prev    next >
Encoding:
Text File  |  1998-10-04  |  12.8 KB  |  655 lines
  1. ;
  2. ; gfx.s -- an ACE linked library module: graphics functions.
  3. ; Copyright (C) 1998 David Benn
  4. ; 
  5. ; This program is free software; you can redistribute it and/or
  6. ; modify it under the terms of the GNU General Public License
  7. ; as published by the Free Software Foundation; either version 2
  8. ; of the License, or (at your option) any later version.
  9. ;
  10. ; This program is distributed in the hope that it will be useful,
  11. ; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12. ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13. ; GNU General Public License for more details.
  14. ;
  15. ; You should have received a copy of the GNU General Public License
  16. ; along with this program; if not, write to the Free Software
  17. ; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
  18. ;
  19. ; Author: David J Benn
  20. ;   Date: 3rd-30th November, 1st-13th December 1991,
  21. ;      20th, 23rd,25th-27th January 1992, 
  22. ;         2nd,4th,6th,12th-19th,21st-24th,29th February 1992,
  23. ;      1st,14th March 1992,
  24. ;      4th,7th,21st,22nd,26th April 1992,
  25. ;      2nd,3rd,5th,7th,8th,10th-17th May 1992,
  26. ;      6th,8th,11th,12th,28th,30th June 1992,
  27. ;      1st-3rd,13th,14th,18th-20th,22nd July 1992,
  28. ;      9th August 1992,
  29. ;      5th,12th,13th December 1992,
  30. ;      20th,21st January 1993,
  31. ;      1st March 1993,
  32. ;      19th March 1994
  33. ;
  34. ; registers d0-d6 and a0-a3 are modified by some of the following. BEWARE!
  35. ;
  36. ; a4,a5 are used by link/unlk.
  37. ; a6 is library base holder.
  38. ; a7 is stack pointer. 
  39. ; d7 is used for array index calculations.
  40. ;
  41.  
  42. ;* RastPort CONSTANTS *
  43. AreaInfo    EQU    16
  44. TmpRas        EQU    12
  45. LinePtrn    EQU    34
  46. AOlPen        EQU    27
  47. Flags        EQU    32
  48. linepatcnt    EQU    30
  49. AreaPtrn    EQU    8
  50. AreaPtSz    EQU    29
  51.  
  52.     ; graphics routines
  53.     xdef    _ellipse
  54.     xdef    _paint
  55.     xdef    _area
  56.     xdef    _areafill
  57.     xdef    _last_areaX
  58.     xdef    _last_areaY
  59.     xdef    _linepattern
  60.     xdef    _areapattern
  61.  
  62.        ; external references
  63.     xref    _radconv
  64.  
  65.     xref    _GfxBase
  66.     xref    _RPort
  67.     xref    _fgdpen
  68.     xref    _LVOWritePixel
  69.     xref    _LVODrawEllipse
  70.     xref    _LVOSetAPen
  71.     xref    _LVOInitArea
  72.     xref    _LVOAllocRaster
  73.     xref    _LVOFreeRaster
  74.     xref    _LVOInitTmpRas
  75.     xref    _LVOFlood
  76.     xref    _LVOAreaDraw
  77.     xref    _LVOAreaEnd
  78.     xref    _LVOAreaMove
  79.     xref    _windowfunc
  80.     xref    _MathBase
  81.     xref    _MathTransBase
  82.     xref    _LVOSPFix
  83.     xref    _LVOSPFlt
  84.     xref    _LVOSPFloor
  85.     xref    _LVOSPAdd
  86.     xref    _LVOSPMul
  87.     xref    _LVOSPDiv
  88.     xref    _LVOSPCmp
  89.     xref    _LVOSPCos
  90.     xref    _LVOSPSin
  91.     xref    _LVOSPLog
  92.  
  93.     SECTION graphics_code,CODE
  94.  
  95. ;
  96. ; ELLIPSE - draw a circle or ellipse. 
  97. ;        d0=x,d1=y,d2=radius,d3=start,d4=end,d5=aspect.
  98. ;
  99. ;      - if full ellipse (0-359 degs) -> use DrawEllipse()
  100. ;        otherwise use my own ellipse algorithm (ie: for arcs).
  101. ;
  102. _ellipse:
  103.     ; store parameters
  104.     move.l    d0,_x
  105.     move.l    d1,_y
  106.     move.l    d2,_radius
  107.     move.l    d3,_startangle
  108.     move.l    d4,_endangle
  109.     move.l    d5,_aspect
  110.     
  111.     ; * is it a full ellipse? *
  112.     
  113.     ; start angle=0? (start must = 0 AND end must = 359)
  114.     cmpi.l    #0,d3
  115.     bne    _do_my_ellipse        ; start <> 0 -> use my algorithm
  116.     
  117.     ; end angle=359?
  118.     movea.l    _MathBase,a6
  119.     move.l    d4,d0
  120.     move.l    #$b3800049,d1        ; 359 (FFP)
  121.     jsr    _LVOSPCmp(a6)
  122.     bne    _do_my_ellipse        ; end <> 359 -> use my algorithm
  123.  
  124.     ; * use faster DrawEllipse() *
  125.     
  126.     ; make x and y integers
  127.     move.l    _x,d0
  128.     jsr    _LVOSPFix(a6)
  129.     move.l    d0,_x
  130.     
  131.     move.l    _y,d0
  132.     jsr    _LVOSPFix(a6)
  133.     move.l    d0,_y
  134.     
  135.     ; calculate x radius and coerce
  136.     move.l    _radius,d0
  137.     move.l    _aspect,d1
  138.     jsr    _LVOSPDiv(a6)
  139.     jsr    _LVOSPFix(a6)
  140.     move.l    d0,_xradius
  141.  
  142.     ; coerce radius 
  143.     move.l    _radius,d0
  144.     jsr    _LVOSPFix(a6)
  145.     cmpi.l    #0,d0
  146.     bne.s    _store_radius
  147.     add.l    #1,_radius        ; vertical radius must be > 0
  148. _store_radius:
  149.     move.l    d0,_radius
  150.  
  151.     ; draw ellipse
  152.     movea.l    _GfxBase,a6    
  153.     move.l    _RPort,a1
  154.     move.l    _x,d0
  155.     and.w    #$ffff,d0
  156.     move.l    _y,d1
  157.     and.w    #$ffff,d1
  158.     move.l    _xradius,d2
  159.     and.w    #$ffff,d2
  160.     move.l    _radius,d3
  161.     and.w    #$ffff,d3
  162.     jsr    _LVODrawEllipse(a6)
  163.  
  164.     rts
  165.     
  166. _do_my_ellipse:    
  167.     ; calculate x-radius based upon aspect and radius
  168.     move.l    _radius,d0
  169.     move.l    _aspect,d1
  170.     movea.l    _MathBase,a6
  171.     jsr    _LVOSPDiv(a6)
  172.     move.l    d0,_xradius
  173.  
  174.     ; initial loop value 
  175.     move.l    _startangle,_theta
  176.  
  177. _plotellipse:
  178.     ; calculate x-point (x-point = x + xradius*cos(theta/radconv)
  179.     move.l    _theta,d0
  180.     move.l    _radconv,d1
  181.     movea.l    _MathBase,a6
  182.     jsr    _LVOSPDiv(a6)
  183.     movea.l    _MathTransBase,a6
  184.     jsr    _LVOSPCos(a6)
  185.     move.l    _xradius,d1
  186.     movea.l    _MathBase,a6
  187.     jsr    _LVOSPMul(a6)
  188.     move.l    _x,d1
  189.     jsr    _LVOSPAdd(a6)
  190.     jsr    _LVOSPFix(a6)
  191. ;    and.w    #$ffff,d0
  192.     move.w    d0,_outx
  193.  
  194.     ; calculate y-point (y-point = y + radius*sin(theta/radconv)
  195.     move.l    _theta,d0
  196.     move.l    _radconv,d1
  197.     movea.l    _MathBase,a6
  198.     jsr    _LVOSPDiv(a6)
  199.     movea.l    _MathTransBase,a6
  200.     jsr    _LVOSPSin(a6)
  201.     move.l    _radius,d1
  202.     movea.l    _MathBase,a6
  203.     jsr    _LVOSPMul(a6)
  204.     move.l    _y,d1
  205.     jsr    _LVOSPAdd(a6)
  206.     jsr    _LVOSPFix(a6)
  207. ;    and.w    #$ffff,d0
  208.     move.w    d0,_outy
  209.     
  210.     ; plot point
  211.     movea.l    _RPort,a1
  212.     move.w    _outx,d0
  213.     move.w    _outy,d1
  214.     movea.l    _GfxBase,a6
  215.     jsr    _LVOWritePixel(a6)
  216.  
  217.     ; increment angle by .5
  218.      move.l    _theta,d0
  219.     move.l    #$80000040,d1
  220.     movea.l    _MathBase,a6
  221.     jsr    _LVOSPAdd(a6)
  222.     move.l    d0,_theta
  223.  
  224.     ; still more to do?  (is theta <= endangle?)
  225.     move.l    _theta,d0
  226.     move.l    _endangle,d1
  227.     jsr    _LVOSPCmp(a6)
  228.     ble    _plotellipse
  229.  
  230.     rts
  231.  
  232. ;
  233. ; RASSIZE     - d0=x,d1=y
  234. ;        - result returned in d0
  235. ;        - see graphics/gfx.h
  236. ;
  237. _rassize:
  238.     add.l    #15,d0
  239.     asr.l    #3,d0
  240.     and.w    #$fffe,d0
  241.     and.w    #$ffff,d1
  242.     mulu    d1,d0    
  243.     rts
  244.  
  245. ;
  246. ; PAINT. d0=X,d1=Y,d2=paintcolor-id,d3=bordercolor-id.
  247. ;
  248. _paint:
  249.     ; store coordinates.
  250.     move.w    d0,_paint_x
  251.     move.w    d1,_paint_y
  252.     
  253.     ; store old fgdpen
  254.     move.w    _fgdpen,_oldfgdpen
  255.         
  256.     ; check colours
  257.     cmpi.w    #-1,d2
  258.     bne.s    _checkbordercolr
  259.     move.w    _fgdpen,d2    ; if paintcolor-id=-1 
  260.                 ; -> paintcolor-id=_fgdpen    
  261.  
  262. _checkbordercolr:
  263.     cmpi.w    #-1,d3
  264.     bne.s    _storecolrs
  265.     move.w    d2,d3        ; if bordercolor-id=-1 
  266.                 ; -> bordercolor-id=_fgdpen
  267.  
  268. _storecolrs:
  269.     move.w    d2,_paintcolr
  270.     move.w    d3,_bordercolr
  271.     
  272.     ; initialise a vector collection matrix.
  273. ;    movea.l    _GfxBase,a6
  274. ;    lea    _ainfo,a0
  275. ;    lea    _areabuf,a1
  276. ;    move.w    #160,d0        ; ???
  277. ;    jsr    _LVOInitArea(a6)
  278. ;    movea.l    _RPort,a0
  279. ;    move.l    #_ainfo,AreaInfo(a0)
  280.     
  281.     ; allocate space for a bitplane
  282.     move.w    #2,d0
  283.     jsr    _windowfunc
  284.     move.l    d0,_WdwWidth    ; get width of current window
  285.  
  286.     move.w    #3,d0
  287.     jsr    _windowfunc
  288.     move.l    d0,_WdwHeight    ; get height of current window
  289.  
  290.     movea.l    _GfxBase,a6
  291.     move.l    _WdwWidth,d0
  292.     move.l    _WdwHeight,d1
  293.     jsr    _LVOAllocRaster(a6)
  294.     move.l    d0,_tbuf    ; store planeptr
  295.     cmpi.l    #0,d0
  296.     beq    _quitpaint    ; quit if can't allocate space.
  297.  
  298.     ; initialise area of local memory for Flood()
  299.     movea.l    _GfxBase,a6
  300.     lea    _tras,a0
  301.     move.l    _tbuf,a1
  302.     move.l    _WdwWidth,d0
  303.     move.l    _WdwHeight,d1
  304.     jsr    _rassize
  305.     jsr    _LVOInitTmpRas(a6)
  306.     movea.l    _RPort,a0
  307.     move.l    #_tras,TmpRas(a0)    ; store pointer to TmpRas
  308.  
  309.     ; set border and foreground pens
  310.     move.l    _RPort,a0
  311.  
  312.     move.b    AOlPen(a0),_oldbordercolr
  313.     move.w    _bordercolr,d0
  314.     and.b    #$ff,d0
  315.     move.b    d0,AOlPen(a0)     ; set outline pen
  316.     ori.w    #$0008,Flags(a0) ; set areaoutline flag 
  317.                  ; (see graphics/gfxmacros.h)
  318.  
  319.     move.w    _paintcolr,d0
  320.     and.b    #$ff,d0
  321.     move.l    _RPort,a1
  322.     movea.l    _GfxBase,a6
  323.     jsr    _LVOSetAPen(a6)
  324.  
  325.     ; flood area enclosed by bordercolr
  326.     movea.l    _GfxBase,a6
  327.     move.l    _RPort,a1
  328.     move.l    #0,d2        ; mode=fill all adjacent pixels 
  329.                 ; searching for border.
  330.     move.w    _paint_x,d0
  331.     move.w    _paint_y,d1
  332.     jsr    _LVOFlood(a6)
  333.  
  334.     ; reset foreground pen
  335.     move.w    _oldfgdpen,d0
  336.     and.b    #$ff,d0
  337.     move.l    _RPort,a1
  338.     movea.l    _GfxBase,a6
  339.     jsr    _LVOSetAPen(a6)
  340.  
  341.     ; reset border color
  342.     movea.l    _RPort,a0    
  343.     move.b    _oldbordercolr,AOlPen(a0) ; set outline pen
  344.     ori.w    #$0008,Flags(a0)        ; set areaoutline flag 
  345.                         ; (see graphics/gfxmacros.h)
  346.  
  347.     ; free TmpRas memory
  348.     movea.l    _GfxBase,a6
  349.     move.l    _tbuf,a0
  350.     move.l    _WdwWidth,d0
  351.     move.l    _WdwHeight,d1
  352.     jsr    _LVOFreeRaster(a6)
  353.     
  354. _quitpaint:
  355.     movea.l    _RPort,a0
  356.     move.l    #0,TmpRas(a0)
  357.     rts    
  358.  
  359. ;
  360. ; AREA - d0=x,d1=y.
  361. ;
  362. _area:
  363.     ; 20 points already?
  364.     move.l    _areaptcount,d2
  365.     cmpi.l    #20,d2
  366.     beq    _quitarea
  367.  
  368.     ; store x,y
  369.     move.w    d0,_areaX
  370.     move.w    d1,_areaY
  371.     
  372.     ; has at least 1 point already been defined?
  373.     cmpi.l    #1,_areaptcount
  374.     bge.s    _add_coord_to_area    ; yes -> just add point to area info
  375.  
  376.     ; initialise rastport's AreaInfo structure
  377.     movea.l    _GfxBase,a6
  378.     lea    _areainfo,a0
  379.     lea    _areabuffer,a1
  380.     move.w    #21,d0        ; 20 points (need 20 + 1 for this to work)
  381.     jsr    _LVOInitArea(a6)
  382.     movea.l    _RPort,a0
  383.     move.l    #_areainfo,AreaInfo(a0)    ; Rastport->AreaInfo = areainfo
  384.     
  385.     ; first point of area
  386.     movea.l    _GfxBase,a6
  387.     movea.l    _RPort,a1
  388.     move.w    _areaX,d0
  389.     move.w    _areaY,d1
  390.     jsr    _LVOAreaMove(a6)
  391.  
  392.     bra.s    _increment_pt_count            
  393.     
  394. _add_coord_to_area:
  395.     ; add point to area info
  396.        ; (if no room left for another point, AreaDraw will return -1)
  397.     movea.l    _GfxBase,a6
  398.     movea.l    _RPort,a1
  399.     move.w    _areaX,d0
  400.     move.w    _areaY,d1
  401.     jsr    _LVOAreaDraw(a6)
  402.  
  403. _increment_pt_count:
  404.     ; was AreaDraw/Move was successful?
  405.       cmpi.l    #0,d0
  406.     bne.s    _quitarea    
  407.  
  408.     ; increment point counter
  409.     add.l    #1,_areaptcount        
  410.  
  411.     ; store last X & Y
  412.     move.w    _areaX,_last_areaX
  413.     move.w    _areaY,_last_areaY
  414.  
  415. _quitarea:
  416.     rts
  417.  
  418. ;
  419. ; AREAFILL - d0=mode.
  420. ;
  421. _areafill:
  422. ;    bra    _quitareafill
  423.  
  424.     ; save current pen
  425.     move.w    _fgdpen,_oldfgdpen
  426.  
  427.     ; check mode (0=fill normally; 1=fill with inverted color)
  428.     cmpi.w    #0,d0
  429.     beq.s    _justfillarea
  430.     
  431.     ; change foreground pen to max-color-id - fdgpen
  432.     move.l    #6,d0
  433.     jsr    _windowfunc    ; d0 = max-color-id for Rasport
  434.     
  435.     move.w    _fgdpen,d1
  436.     ext.l    d1
  437.     sub.l    d1,d0        ; d0 = d0 - _fgdpen
  438.  
  439.     movea.l    _GfxBase,a6
  440.     movea.l    _RPort,a1
  441.     jsr    _LVOSetAPen(a6)
  442.     
  443. _justfillarea:
  444.     ; have at least 2 points been defined?
  445.     cmpi.l    #2,_areaptcount
  446.     blt    _quitareafill    ; no -> go no further
  447.  
  448.     ; initialise rastport's TmpRas structure    
  449.     move.w    #2,d0
  450.     jsr    _windowfunc
  451.     move.l    d0,_WdwWidth    ; get width of current window
  452.  
  453.     move.w    #3,d0
  454.     jsr    _windowfunc
  455.     move.l    d0,_WdwHeight    ; get height of current window
  456.  
  457.     movea.l    _GfxBase,a6
  458.     move.l    _WdwWidth,d0
  459.     move.l    _WdwHeight,d1
  460.     jsr    _LVOAllocRaster(a6)
  461.     cmpi.l    #0,d0
  462.     beq    _quitareafill
  463.     move.l    d0,_TRBuf    ; store pointer to buffer
  464.  
  465.     movea.l    _GfxBase,a6
  466.     move.l    _WdwWidth,d0
  467.     move.l    _WdwHeight,d1
  468.     jsr    _rassize    ; result in d0 = plane size in bytes (not bits!)
  469.     lea    _tmpras,a0
  470.     movea.l    _TRBuf,a1
  471.     jsr    _LVOInitTmpRas(a6)
  472.     movea.l    _RPort,a0
  473.     move.l    #_tmpras,TmpRas(a0)    ; Rastport->TmpRas = tmpras    
  474.  
  475.     ; ** fill defined area! **
  476.     movea.l    _GfxBase,a6
  477.     movea.l    _RPort,a1
  478.     jsr    _LVOAreaEnd(a6)
  479.  
  480.     ; restore old fgnd color
  481.     movea.l    _GfxBase,a6
  482.     movea.l    _RPort,a1
  483.     move.w    _oldfgdpen,d0
  484.     ext.l    d0
  485.     jsr    _LVOSetAPen(a6)
  486.     move.w    _oldfgdpen,_fgdpen
  487.  
  488.     ; free buffer
  489.     movea.l    _GfxBase,a6
  490.     movea.l    _TRBuf,a0
  491.     move.l    _WdwWidth,d0
  492.     move.l    _WdwHeight,d1    
  493.     jsr    _LVOFreeRaster(a6)
  494.         
  495. _quitareafill:
  496.     ; get ready for next area
  497.     move.l    #0,_areaptcount    ; # of points = 0
  498.     movea.l    _RPort,a0
  499.     move.l    #0,TmpRas(a0)    ; Rp->TmpRas = NULL
  500.     move.l    #0,AreaInfo(a0)    ; Rp->AreaInfo = NULL
  501.     rts
  502.  
  503. ;
  504. ; PATTERN - linepattern: d0=line-pattern.
  505. ;             d1=RESTORE flag.
  506. ;
  507. ;      - see graphics/gfxmacros.h: SetDrPt()
  508. ;
  509. _linepattern:
  510.     ; get current RastPort
  511.     movea.l    _RPort,a1
  512.  
  513.     ; new line pattern or restore default?
  514.     cmpi.l    #0,d1
  515.     beq.s    _newlinepattern
  516.  
  517.     ; restore default
  518.     move.w    #$ffff,LinePtrn(a1)
  519.     bra.s    _finishlinepattern
  520.  
  521. _newlinepattern:
  522.     move.w    d0,LinePtrn(a1)
  523.  
  524. _finishlinepattern:
  525.     ori.w    #$0001,Flags(a1)
  526.     move.b    #15,linepatcnt(a1)
  527.  
  528.     rts
  529.  
  530. ;
  531. ; PATTERN - areapattern: a0=address of area-pattern array.
  532. ;             d0=size of area-pattern array.
  533. ;             d1=RESTORE flag.
  534. ;
  535. ;      - see graphics/gfxmacros.h: SetAfPt()  
  536. ;        and "Inside Amiga Graphics", pp 116,117
  537. ;
  538. _areapattern:
  539.     ; new area pattern or restore default?
  540.     cmpi.l    #0,d1
  541.     beq.s    _newareapattern
  542.  
  543.     ; restore default
  544.     movea.l    _RPort,a1
  545.     move.l    #_default_area_pat,AreaPtrn(a1)
  546.     move.b    #0,AreaPtSz(a1)    ; height = 2^0 = 1 (ie: height in short words)
  547.     bra.s    _exitareapattern
  548.  
  549. _newareapattern:
  550.     move.l    a0,AreaPtrn(a1)    ; address of area pattern array    
  551.  
  552.     ; find Log2(size): LogE(areapat_size) / LogE(2)
  553.     movea.l    _MathBase,a6
  554.     jsr    _LVOSPFlt(a6)    ; d0 = (float)d0
  555.     movea.l    _MathTransBase,a6
  556.     jsr    _LVOSPLog(a6)
  557.     move.l    d0,-(sp)    ; save result of LogE(size)
  558.  
  559.     move.l    #$80000042,d0    ; 2.0
  560.     jsr    _LVOSPLog(a6)
  561.  
  562.     move.l    d0,d1        ; LogE(2)
  563.     move.l    (sp)+,d0    ; LogE(size)
  564.     movea.l    _MathBase,a6
  565.     jsr    _LVOSPDiv(a6)
  566.  
  567.     jsr    _LVOSPFloor(a6)    ; round it
  568.     jsr    _LVOSPFix(a6)    ; d0 = (long)d0
  569.  
  570.     movea.l    _RPort,a1
  571.     move.b    d0,AreaPtSz(a1)    ; height = 2^d0            
  572.         
  573. _exitareapattern:
  574.     rts
  575.  
  576. ;*********************************
  577.  
  578.     SECTION graphics_data,DATA
  579.  
  580. ; * paint *
  581. _tras:            
  582.     dc.l 0
  583.     dc.l 0
  584.  
  585. _ainfo:    
  586.     dc.l 0
  587.     dc.l 0
  588.     dc.l 0
  589.     dc.l 0
  590.     dc.w 0
  591.     dc.w 0
  592.     dc.w 0
  593.     dc.w 0
  594.  
  595. ; * area *
  596. _areainfo:
  597.     dc.l 0
  598.     dc.l 0
  599.     dc.l 0
  600.     dc.l 0
  601.     dc.w 0
  602.     dc.w 0
  603.     dc.w 0
  604.     dc.w 0
  605.     
  606. _tmpras:    
  607.     dc.l 0
  608.     dc.l 0
  609.  
  610. _areaptcount:    dc.l 0    ; has an area been started?        
  611.  
  612. ; * pattern *
  613. _default_area_pat:    dc.w $ffff
  614.  
  615. ;************************
  616.  
  617.     SECTION graphics_mem,BSS
  618.  
  619. ; * general *
  620. _WdwWidth:        ds.l 1
  621. _WdwHeight:        ds.l 1
  622.  
  623. ; * ellipse *
  624. _x:            ds.l 1
  625. _y:            ds.l 1
  626. _radius:        ds.l 1
  627. _xradius:        ds.l 1
  628. _startangle:        ds.l 1
  629. _endangle:        ds.l 1
  630. _aspect:        ds.l 1
  631. _theta:            ds.l 1
  632. _outx:            ds.w 1
  633. _outy:            ds.w 1
  634.  
  635. ; * paint *
  636. _areabuf:        ds.w 800
  637. _tbuf:            ds.l 1
  638. _paintcolr:        ds.w 1
  639. _bordercolr:        ds.w 1
  640. _oldbordercolr:        ds.b 1
  641. _paint_x:        ds.w 1
  642. _paint_y:        ds.w 1
  643. _oldfgdpen:        ds.w 1
  644. _border:        ds.w 1
  645.  
  646. ; * area *
  647. _areabuffer:        ds.w 53        ; buffer for 20+1 SHORT points (21x2.5)
  648. _areaX:            ds.w 1
  649. _areaY:            ds.w 1
  650. _last_areaX:        ds.w 1          
  651. _last_areaY:        ds.w 1      ; _last_areaX/Y    for use by AREA STEP...
  652. _TRBuf:            ds.l 1
  653.  
  654.     END
  655.